‏הצגת רשומות עם תוויות סאסוד. הצג את כל הרשומות
‏הצגת רשומות עם תוויות סאסוד. הצג את כל הרשומות

יום שבת, 21 ביולי 2012

התמזגות, התאחדות, התערבבות

ערכים חסרים (missing) אינם זרים למרבית משתמשי ה – SAS. ב – SAS ערך חסר בעמודה נומרית מיוצג ע"י נקודה ואילו ערך חסר בעמודת טקסט מיוצג ע"י מחרוזת ריקה ("") או מחרוזת המכילה רווח אחד (" "). SAS אפילו מגדילה לעשות ומאפשרת לנו להגדיר 28 סוגים של ערכים נומרים חסרים. למה זה טוב אתם שואלים? ובכן זה מאפשר לנו לציין בצורה פשוטה לא רק שהערך חסר אלא גם את הסיבה לכך. לדוגמא, אם אנחנו מנתחים נתוני סקר ניתן להבדיל בין 'המשתמש לא ענה בכלל', 'המשתמש בחר באפשרות "לא רלוונטי"' ו – "לא הצלחנו להבין מה המשתמש ענה".
הרעיון של "ערך חסר " מונח בבסיס תיאוריית בסיס הנתונים הרלציוני (טבלאי) וכל בסיס נתונים כלשהו מאפשר ייצוג העובדה שתא כלשהו בטבלה איננו מכיל כלום. לרוב בהקשר של בסיסי נתונים ערך חסר מכונה NULL.
לטיפול בערכים חסרים קיימות ב – SAS מספר פונקציות ייעודיות ואחת השימושיות והנחבאות שבהן היא COALESCE. הפונקציה הזו מקבלת פרמטר אחד או יותר ומחזירה את הראשון (משמאל לימין) שהוא לא חסר או NULL. לדוגמא:

data sample;
length n1 n2 8 c1 c2 $1;
input n1 n2 c1 $ c2 $;
infile datalines dsd delimiter=',';
datalines;
1,2,X,Y
.,3,,Z
.,.,,
;
run;

proc print data=sample;
title 'Dataset: SAMPLE';
run;

proc sql;
create table sample_sql as
select
n1,
n2,
c1,
c2,
coalesce(n1,n2,4) as n3,
coalesce(n1,n2) as n4,
coalesce(c1,c2,'T') as c3,
coalesce(c1,c2) as c4
from
sample;
quit;

proc print data=sample_sql;
title 'Dataset: SAMPLE_SQL';
run;

נקודה שצריך לשים לה לב היא שכאשר משתמשים בפונקציה זו בתוך PROC SQL היא יודעת לטפל בערכים נומרים וטקסטואלים כאחד אבל אם אנחנו רוצים להשתמש בה בתוך DATA Step אז היא יודעת לעבוד עם ערכים נומרים בלבד. עבור שדות טקסטואלים צריך לקרוא לאחותה COALESCEC – עם האות C (בשביל character) בסוף. לדוגמא:

data sample_datastep;
set sample;
length n3 n4 8 c3 c4 $1;
n3=coalesce(n1,n2,4);
n4=coalesce(n1,n2);
c3=coalescec(c1,c2,'T');
c4=coalescec(c1,c2);
run;

proc print data=sample_datastep;
title 'Dataset: SAMPLE_DATASTEP';
run;

ולסיום, למי שתהה על כותרת הפוסט הזה אזי המילה coalesce באנגלית פירושה התמזגות, התאחדות, התערבבות וממנה הגיעה המילה קואליציה.
חגי

יום שבת, 31 במרץ 2012

סאסוד

עבר לא מעט זמן מאז הפוסט האחרון שלי אבל אני מקווה שמעכשיו אצליח לשמור על תדירות פרסום פחות או יותר קבועה.

לפני שניגש לנושא שלשמו התכנסנו אני רוצה להודות ל – Rottman ולאפרת זילברמן על התגובות שלהם לפוסטים קודמים שלי. אחת ממטרות בלוג זה הוא לעודד רב-שיח ושיתוף בין משתמשי ה – SAS בארץ כך שתגובות, הערות והארות תמיד יתקבלו בברכה.

ולעניינו. שפת ה – SAS עשירה מאוד וכוללת אלפי פקודות ופונקציות שונות. חלקן ידועות ונמצאות בשימוש כמעט בכל יום ע"י משתמשי ה - SAS אולם חלקן ידוע פחות. מידי פעם אני נתקל בפרמטרים, פונקציות ואפילו ב - PROC-ים שלמים המתחבאים אל הכלים ופחות ידועים בברנז'ה אבל יכולים לחסוך לנו עבודה רבה אם נכיר אותם ונדע להשתמש בהם במקום ובזמן הנכון.

לכן, החלטתי לייסד פינה חדשה בבלוג זה בשם סאסוד (סאס + סוד – מחוכם, הא...) בה נוציא לאור הזרקורים אופציות, פונקציות ויכולות של SAS שהן אולי פחות מוכרות אבל בהחלט שימושיות.

לפני שנמשיך, אזהרה – הן פוסט זה והן מרבית הפוסטים העתידיים בפינה זו יעסקו בנושאים מתקדמים ב – SAS כך שאם אתם חדשים בכל הקטע הזה של SAS יכול להיות שיהיה לכם קצת קשה להתחבר. בכל מקרה, בכוונתי גם להתחיל בקרוב פינה נוספת המיועדת במיוחד למשתמשים חדשים ב – SAS (עדיין לא מצאתי שם, הצעות יתקבלו בברכה) כך שכולם ייצאו מרוצים.

בחרתי להתחיל עם פונקציית מאקרו ידועה בשם %SYSFUNC. פונקציה זו מאפשרת לנו להפעיל מתוך שפת המאקרו של SAS פונקציות "רגילות" של SAS. מה שפחות ידוע הוא שפונקציית מאקרו זו יכולה לקבל פרמטר נוסף שהוא הפורמט בו יעשה שימוש לעצב את התוצר המתקבל מפונקציית ה – SAS.

דוגמא מהחיים:
בתוכנית ה – SAS שלנו אנחנו רוצים להוסיף הערת-שוליים (footnote) המכילה את תאריך נכונות הנתונים. הדרך הפשוטה לעשות זאת היא:

footnote ‘Data as of 28/03/2012’;
proc print data=sashelp.class noobs;
      where age=13;
run;

ובפלט נקבל:

הבעיה היא שבשיטה זו נצטרך כל פעם לעדכן ידנית את התוכנית שלנו עסק שיכול להיות די מתיש ופתח לטעויות מביכות.

אם הצלחנו לאסוף ידע בסיסי בשפת המאקרו של SAS נראה שנוכל לפתור את בעיית העדכון בצורה פשוטה ע"י שינוי ה – footnote בצורה הבאה:

footnote "Data as of %sysfunc(today())";
*footnote "Data as of %sysfunc(date())";
proc print data=sashelp.class noobs;
      where age=13;
run;


כאמור, פונקציית המאקרו %sysfunc מאפשרת לנו לקרוא לפונקציות "רגילות" של SAS כגון today() המחזירה לנו את התאריך של הרצת הקוד (הפונקציה date() עושה בדיוק אותו דבר). חשוב, כמובן, לזכור לשנות את המרכאות הבודדות למרכאות כפולות אחרת העסק לא יעבוד.

הבעיה היא שהפלט שנקבל יהיה אומנם נכון טכנית – מה – 1/1/1960 ועד ה – 28/3/2012 אכן עברו 19080 ימים – אבל פחות נוח לקריאה ע"י בני אדם:


פתרון אחד הוא שימוש שוב ב - %sysfunc לקריאה לפונקציה putn() שבעזרתה נעצב את התאריך בצורה מתאימה לצריכה אנושית:
footnote "Data as of %sysfunc(putn(%sysfunc(today()),ddmmyy10.))";
proc print data=sashelp.class noobs;
      where age=13;
run;

ונקבל שוב:


הבעיה שהסוגריים מתחילים להשתולל בקוד שלנו ובאופן כללי הוא נהיה די ארוך.

הפתרון האלגנטי במקרים שכאלו הוא שימוש בפרמטר השני והסודי של %sysfunc לעיצוב התאריך:

footnote "Data as of %sysfunc(today(),ddmmyy10.)";
proc print data=sashelp.class noobs;
      where age=13;
run;

שגם הוא ייתן לנו:

אבל עם פחות קוד ועם הרבה פחות סוגריים.

כמובן שניתן להשתמש בשיטה זו לעיצוב כל מספר או טקסט שהוא ולא בהכרח תאריכים:

footnote "Daily percent:%sysfunc(ranuni(0),percentn5.0)";
proc print data=sashelp.class noobs;
      where age=13;
run;

חגי